Ciao MdM,
'------------------
Sto provando a concatenare le celle di due colonne, una delle quali è
iscritta in corsivo. Si può fare in modo che concatenando non si perda
il formato e la colonna risultato sia scritta mezza in plain e mezza in
corsivo?
'------------------
Prova qualcosa del genere:
'==========>>
Public Sub Tester()
Dim WB As Workbook
Dim SH As Worksheet
Dim Rng As Range
Dim destRng As Range
Dim rCell As Range
Dim i As Long, j As Long
Set WB = Workbooks("Pippo.xls") '<<=== da CAMBIARE
Set SH = WB.Sheets("Foglio1") '<<=== da CAMBIARE
Set Rng = SH.Range("A1:A100") '<<=== da CAMBIARE
For Each rCell In Rng.Cells
With rCell
Set destRng = .Offset(0, 2)
i = Len(.Text)
j = Len(.Offset(0, 1).Text)
destRng.Value = .Text & " " & .Offset(0, 1).Value
End With
With destRng.Characters(Start:=i + 2, Length:=j).Font
.Italic = True
.ColorIndex = 3
End With
Next rCell
End Sub
'<<==========
Per utilizzare questa routine:
Alt-F11 per aprire l'Editor di VBA
Menu | Inserisci | Modulo
Incolla il suddetto codice
Alt-F11 per tornare in Excel
Alt-F8
Seleziona "Tester"
Esegui
---
Regards,
Norman