Ciao Francesco,
'=============
Perfetto, come sempre !!!
Ma se volessi fare come chiedevo
Post by Frank- Creare una selezione di celle in Foglio1 partendo da InizioSel (A1)
per 8 colonne fino all'ultima riga non vuota
- copiare ed incollare in Foglio2 partendo da InizioIncolla (A1)
cioe' dare un nome alla cella di inizio della copia (InizioSel) e inizio
dell'incolla (InizioIncolla) come si fa ?
Ho provato ma mi fa sempre casino ...
=============
Non sono sicuro di avere capito ho capito -
o, meglio non sono sicuro di avere capito lo
scopo della tua domanda.
Tuttavia, alla testa di un modulo standard,
prima di qualsiasi altro codice, prova
qualcosa del genere:
'==========>>
Option Explicit
Const sName As String = "InizioSel"
Const sName2 As String = "InizioIncolla"
'-------------->>
Public Sub Tester()
Dim WB As Workbook
Dim srcSH As Worksheet
Dim destSH As Worksheet
Dim srcRng As Range
Dim destRng As Range
Dim iRow As Long
Set WB = Workbooks("book1")
Set srcSH = WB.Sheets("Foglio1")
Set destSH = WB.Sheets("Foglio2")
With srcSH
iRow = LastRow(srcSH, .Range("A:A").Resize(, 8))
Set srcRng = .Range("A1:A" & iRow).Resize(, 8)
End With
Set destRng = destSH.Range("A1")
srcRng.Copy Destination:=destRng
srcRng.Name = sName
destRng.Name = sName2
Call demo
End Sub
'-------------->>
Public Sub demo()
With ThisWorkbook
MsgBox Prompt:="il nome " & sName _
& " si riferice all'intervallo " _
& .Names(sName).RefersToRange. _
Address(External:=True) _
& vbNewLine & vbNewLine _
& "il nome " & sName2 _
& " si riferice all'intervallo " _
& .Names(sName2).RefersToRange. _
Address(External:=True), _
Buttons:=vbInformation, _
Title:="Demo"
End With
End Sub
'-------------->>
Function LastRow(SH As Worksheet, _
Optional Rng As Range)
If Rng Is Nothing Then
Set Rng = SH.Cells
End If
On Error Resume Next
LastRow = Rng.Find(What:="*", _
After:=Rng.Cells(1), _
LookAt:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
On Error GoTo 0
End Function
'<<=========
Comunque, se vuoi spiegare la tua esigenza,
forse potrei fare altri suggerimenti.
---
Regards.
Norman